他のバージョンの文書 15 | 14 | 13 | 12 | 11 | 10 | 9.6 | 9.5 | 9.4 | 9.3 | 9.2 | 9.1 | 9.0 | 8.4 | 8.3 | 8.2 | 8.1 | 8.0 | 7.4 | 7.3 | 7.2

37.11. Oracle PL/SQLからの移植

本節ではOracleからPostgreSQLへアプリケーションを移植する開発者の手助けとなるように、 PostgreSQLPL/pgSQL言語とOracleのPL/SQL言語の違いについて説明します。

PL/pgSQLは多くの点でPL/SQLに似ています。 それはブロックで構成されていて、厳格な言語であり、全ての変数は宣言されなければならない点です。 代入やループ、条件分岐も同様です。 PL/SQLからPL/pgSQLに移植する際に注意しなければならない、主な違いを以下に示します。

37.11.1. 移植例

例37-2に簡単な関数のPL/SQLからPL/pgSQLへの移植方法を示します。

例 37-2. 簡単な関数のPL/SQLからPL/pgSQLへの移植

以下はOracle PL/SQLの関数です。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
show errors;

この関数を通じて、PL/pgSQLとの違いを見てみましょう。

  • PostgreSQLには名前付きパラメータはありません。 関数内部で明示的に別名を付ける必要があります。

  • OracleINOUTINOUTというパラメータを関数に渡すことができます。 例えば、INOUTは、パラメータが値を受け取って別の値を返すことを意味します。 PostgreSQLでは"IN"パラメータしかないため、関数は単一の値しか返せません。

  • 関数プロトタイプ内のRETURNキーワード(関数本体ではありません)はPostgreSQLではRETURNSになります。

  • PostgreSQLでは関数を単一引用符を関数本体の区切り文字として使用して作成するため、関数本体内の単一引用符をエスケープしなければいけません

  • PostgreSQLには/show errorsコマンドはありません。

それではPostgreSQLに移植されると、この関数がどのようになるかみてみましょう。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(varchar, varchar)
RETURNS varchar AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        return v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE plpgsql;

例37-3は、他の関数を生成する関数を移植する方法、ならびに、その結果発生する引用符問題を扱う方法を示します。

例 37-3. 他の関数を生成するPL/SQLPL/pgSQLに移植

以下の手続きは、SELECT文からの行をとって、効率のためにIF文で結果を巨大な関数に埋め込んでいます。 特にカーソルとFORループにおける違いに注目してください。

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS
    CURSOR referrer_keys IS 
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    a_output VARCHAR(4000); 
BEGIN 
    a_output := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR, v_domain IN VARCHAR, 
v_url IN VARCHAR) RETURN VARCHAR IS BEGIN'; 

    FOR referrer_key IN referrer_keys LOOP 
        a_output := a_output || ' IF v_' || referrer_key.kind || ' LIKE ''' || 
referrer_key.key_string || ''' THEN RETURN ''' || referrer_key.referrer_type || 
'''; END IF;'; 
    END LOOP; 

    a_output := a_output || ' RETURN NULL; END;'; 
    EXECUTE IMMEDIATE a_output; 
END; 
/ 
show errors;

この関数をPostgreSQLで記述するとこうなるでしょう。

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS integer AS '
DECLARE
    referrer_keys RECORD;  -- FOR で使用される汎用レコードを宣言
    a_output varchar(4000);
BEGIN 
    a_output := ''CREATE FUNCTION cs_find_referrer_type(varchar, varchar, varchar) 
                  RETURNS varchar AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3;
                     BEGIN ''; 

    -- FOR <record> 構文を使用した FOR ループで、問い合わせの結果
    -- をどのようにスキャンしているかに注意して下さい。

    FOR referrer_keys IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        a_output := a_output || '' IF v_'' || referrer_keys.kind || '' LIKE '''''''''' 
                 || referrer_keys.key_string || '''''''''' THEN RETURN '''''' 
                 || referrer_keys.referrer_type || ''''''; END IF;''; 
    END LOOP; 
  
    a_output := a_output || '' RETURN NULL; END; '''' LANGUAGE plpgsql;''; 
 
    -- これはどの変数も置き換えていないのでうまくいきます。
    -- さもなければ失敗します。関数を実行する他の方法については PERFORM を参照して下さい。
    
    EXECUTE a_output; 
END; 
' LANGUAGE plpgsql;

例37-4は、OUTパラメータを持ち、文字列操作を行なう関数の移植方法を示します。 PostgreSQLにはinstrはありませんが、他の関数を組み合わせることで回避できます。 項37.11.3に、移植を簡略化できるようにinstrPL/pgSQLによる実装を示します。

例 37-4. 文字列操作を行ない、OUTパラメータを持つPL/SQLプロシージャのPL/pgSQLへの移植

以下のOracle PL/SQLプロシージャは、URLを解析していくつかの要素(ホスト、パス、問い合わせ)を返します。 PL/pgSQL 関数は一つしか値を返すことができません。 PostgreSQLでの回避方法の1つとして、このプロシージャを3つの異なる関数に分割する方法があります。 一つはホストを返し、もう一つはパスを返し、もう一つは問い合わせを返します。

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN VARCHAR,
    v_host OUT VARCHAR,  -- This will be passed back
    v_path OUT VARCHAR,  -- This one too
    v_query OUT VARCHAR) -- And this one
IS
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

ホスト部分を返すPL/pgSQL関数は以下のようになります。

CREATE OR REPLACE FUNCTION cs_parse_url_host(varchar) RETURNS varchar AS '
DECLARE
    v_url ALIAS FOR $1;
    v_host varchar;
    v_path varchar;
    a_pos1 integer;
    a_pos2 integer;
    a_pos3 integer;
BEGIN 
    v_host := NULL; 
    a_pos1 := instr(v_url, ''//'');

    IF a_pos1 = 0 THEN 
        RETURN '''';  -- Return a blank
    END IF; 

    a_pos2 := instr(v_url,''/'',a_pos1 + 2);
    IF a_pos2 = 0 THEN 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        RETURN v_host; 
    END IF; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    RETURN v_host; 
END; 
' LANGUAGE plpgsql;

例37-5は、Oracleに特化した多くの機能を使用したプロシージャの移植方法を示します。

例 37-5. PL/SQLプロシージャのPL/pgSQLへの移植

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id IN INTEGER) IS
    a_running_job_count INTEGER;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- ロックを解放(3)
        raise_application_error(-20000, 'Unable to create a new job: a job is currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, sysdate);
        EXCEPTION WHEN dup_val_on_index THEN NULL; -- 既存であっても問題なし(4)
    END;
    COMMIT;
END;
/
show errors

このようなプロシージャはinteger型を返すPostgreSQL関数に簡単に変換することができます。 これは以下のような事を教えてくれることもあってこのプロシージャは特におもしろいです。

(1)
PostgreSQLにはPRAGMA文はありません。
(2)
PL/pgSQLLOCK TABLEを使用するならば、トランザクションの終了を呼び出すまでロックが解放されません。
(3)
PL/pgSQL関数ではトランザクションを使用することができません。 関数全体(とそこから呼ばれる他の関数)は一つのトランザクションで実行されます。 そして、何か問題がおきたら、PostgreSQLはその結果をロールバックします。
(4)
IF文で置き換える必要のある例外。

それでは、このプロシージャをPL/pgSQLに移植することができた方法を見てみましょう。

CREATE OR REPLACE FUNCTION cs_create_job(integer) RETURNS integer AS '
DECLARE
    v_job_id ALIAS FOR $1;
    a_running_job_count integer;
    a_num integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;
    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0
    THEN
        RAISE EXCEPTION ''Unable to create a new job: a job is currently running.'';
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    SELECT count(*) INTO a_num FROM cs_jobs WHERE job_id=v_job_id;
    IF NOT FOUND THEN  -- 最後の問い合わせで何も返されなかった場合
        -- このジョブはテーブル内にないため、挿入します。
        INSERT INTO cs_jobs(job_id, start_stamp) VALUES (v_job_id, current_timestamp);
        RETURN 1;
    ELSE
        RAISE NOTICE ''Job already running.'';(1)
    END IF;

    RETURN 0;
END;
' LANGUAGE plpgsql;

(1)
PL/pgSQLでnotice(もしくは error )をどのように起こすかに注意して下さい。

37.11.2. その他の注意事項

本節では、Oracle PL/SQL関数のPostgreSQLへの移植における、その他の注意事項を説明します。

37.11.2.1. EXECUTE

PL/pgSQLEXECUTEPL/SQL版とよく似ています。 しかし項37.6.4で説明されているquote_literal(text)quote_string(text)を使うことを覚えておかなければいけません。 これらの関数を使用しない限りEXECUTE ''SELECT * from $1'';という構文は動作しません。

37.11.2.2. PL/pgSQL関数の最適化

PostgreSQLには実行を最適化するために2つの関数生成修飾子があります。 一時性(同じ引数が与えられた場合常に同じ結果が返します)と"厳密性"(引数のいずれかにNULLが含まれる場合NULLを返します)です。 詳細はCREATE FUNCTIONの説明を参照して下さい。

これらの最適化属性を利用するためには、CREATE FUNCTION文を以下のようにします。

CREATE FUNCTION foo(...) RETURNS integer AS '
...
' LANGUAGE plpgsql STRICT IMMUTABLE;

37.11.3. 付録

本節には、移植作業を簡略化するために使用できる、Oracle互換のinstr関数のコードがあります。

--
-- Oracle のものと同じ動作をする instr 関数
-- 構文 :instr(string1,string2,[n],[m]) ただし、[]は省略可能なパラメータ
-- 
-- string1 内の n番目の文字からm番目の文字までで string2 を探します。
-- n が負の場合、逆方向に検索します。 mが渡されなかった場合は、1 と 
-- みなします(最初の文字から検索を始めます)。
--

CREATE FUNCTION instr(varchar, varchar) RETURNS integer AS '
DECLARE
    pos integer;
BEGIN
    pos:= instr($1, $2, 1);
    RETURN pos;
END;
' LANGUAGE plpgsql;


CREATE FUNCTION instr(varchar, varchar, varchar) RETURNS integer AS '
DECLARE
    string ALIAS FOR $1;
    string_to_search ALIAS FOR $2;
    beg_index ALIAS FOR $3;
    pos integer NOT NULL DEFAULT 0;
    temp_str varchar;
    beg integer;
    length integer;
    ss_length integer;
BEGIN
    IF beg_index > 0 THEN
        temp_str := substring(string FROM beg_index);
        pos := position(string_to_search IN temp_str);

        IF pos = 0 THEN
            RETURN 0;
        ELSE
            RETURN pos + beg_index - 1;
        END IF;
    ELSE
        ss_length := char_length(string_to_search);
        length := char_length(string);
        beg := length + beg_index - ss_length + 2;

        WHILE beg > 0 LOOP
            temp_str := substring(string FROM beg FOR ss_length);
            pos := position(string_to_search IN temp_str);

            IF pos > 0 THEN
                RETURN beg;
            END IF;

            beg := beg - 1;
        END LOOP;

        RETURN 0;
    END IF;
END;
' LANGUAGE plpgsql;


CREATE FUNCTION instr(varchar, varchar, integer, integer) RETURNS integer AS '
DECLARE
    string ALIAS FOR $1;
    string_to_search ALIAS FOR $2;
    beg_index ALIAS FOR $3;
    occur_index ALIAS FOR $4;
    pos integer NOT NULL DEFAULT 0;
    occur_number integer NOT NULL DEFAULT 0;
    temp_str varchar;
    beg integer;
    i integer;
    length integer;
    ss_length integer;
BEGIN
    IF beg_index > 0 THEN
        beg := beg_index;
        temp_str := substring(string FROM beg_index);

        FOR i IN 1..occur_index LOOP
            pos := position(string_to_search IN temp_str);

            IF i = 1 THEN
                beg := beg + pos - 1;
            ELSE
                beg := beg + pos;
            END IF;

            temp_str := substring(string FROM beg + 1);
        END LOOP;

        IF pos = 0 THEN
            RETURN 0;
        ELSE
            RETURN beg;
        END IF;
    ELSE
        ss_length := char_length(string_to_search);
        length := char_length(string);
        beg := length + beg_index - ss_length + 2;

        WHILE beg > 0 LOOP
            temp_str := substring(string FROM beg FOR ss_length);
            pos := position(string_to_search IN temp_str);

            IF pos > 0 THEN
                occur_number := occur_number + 1;

                IF occur_number = occur_index THEN
                    RETURN beg;
                END IF;
            END IF;

            beg := beg - 1;
        END LOOP;

        RETURN 0;
    END IF;
END;
' LANGUAGE plpgsql;